Thanks for bringing this to my attention, I will have a chat with itch.io about this.

'
'Simple example of a banner ad in monkey2
'
Namespace myapp

#Import "<std>"
#Import "<mojo>"
#Import "<mojox>"
#Import "<admob>"

Using std..
Using mojo..
Using mojox..
Using admob..

'Replace this with your AdMobID for banner ads, eg: "ca-app-pub-XXXXXXXXXXXXXXXX/YYYYYYYYYY"
'
Const AdMobID:=""

Class MyWindow Extends Window

    Method New( title:String="Simple mojo app",width:Int=640,height:Int=480,flags:WindowFlags=Null )
        Super.New( title,width,height,flags )

        'Scale up GUI a bit on mobile!
        App.Theme.Scale=New Vec2f( 3,3 )

        'Create the ad - will auto show once loaded.
        admob.CreateAd( "banner","top",AdMobID )

        'Add some buttons to hide/show the ad.
        Local tools:=New ToolBar

        tools.AddAction( "Show ad" ).Triggered=Lambda()

            admob.ShowAd()

        End
        tools.AddAction( "Hide Ad" ).Triggered=Lambda()

            admob.HideAd()

        End
        ContentView=tools
    End

    Method OnRender( canvas:Canvas ) Override

        RequestRender()

        Select admob.GetAdState()
        Case admob.AdState.Loading

            canvas.DrawText( "Loading...",Width/2,Height/2,.5,.5 )

        Case admob.AdState.Error

            canvas.DrawText( "Failed to load ad!",Width/2,Height/2,.5,.5 )

        Case admob.AdState.Ready

            canvas.DrawText( "Ad Ready",Width/2,Height/2,.5,.5 )

        End

    End

End

Function Main()
    New AppInstance
    New MyWindow
    App.Run()
End